Dim caption As String = "Example: NewBookmark"
Dim gdpicturePDF As New GdPicturePDF()
Dim status As GdPictureStatus = gdpicturePDF.NewPDF()
If status = GdPictureStatus.OK Then
    gdpicturePDF.SetOrigin(PdfOrigin.PdfOriginTopLeft)
    gdpicturePDF.SetMeasurementUnit(PdfMeasurementUnit.PdfMeasurementUnitCentimeter)
    Dim fontResName As String = gdpicturePDF.AddStandardFont(PdfStandardFont.PdfStandardFontHelvetica)
    If gdpicturePDF.GetStat() = GdPictureStatus.OK Then
        Dim failure As Boolean = True
        Dim rootBookmark As Integer = gdpicturePDF.NewBookmark(0, "Pages Navigation")
        status = gdpicturePDF.GetStat()
        If status <> GdPictureStatus.OK Then
            MessageBox.Show("The NewBookmark() method (root bookmark for pages) has failed with the status: " + status.ToString(), caption)
        Else
            Dim i As Integer = 0
            Do
                i += 1
                If (gdpicturePDF.NewPage(21, 29.7F) = GdPictureStatus.OK) AndAlso
                   (gdpicturePDF.SetFillColor(255, 0, 0) = GdPictureStatus.OK) AndAlso
                   (gdpicturePDF.SetTextSize(12) = GdPictureStatus.OK) AndAlso
                   (gdpicturePDF.DrawText(fontResName, 1, 1, "This is the page " + i.ToString()) = GdPictureStatus.OK) Then
                    Dim actionID As Integer = gdpicturePDF.NewActionGoTo(PdfDestinationType.DestinationTypeXYZ, i, 0, 0, 0, 0, 1)
                    If gdpicturePDF.GetStat() = GdPictureStatus.OK Then
                        Dim bookMarkID As Integer = gdpicturePDF.NewBookmark(rootBookmark, "Move to the page " + i.ToString())
                        If gdpicturePDF.GetStat() = GdPictureStatus.OK Then
                            failure = (gdpicturePDF.SetBookmarkAction(bookMarkID, actionID) <> GdPictureStatus.OK)
                        End If
                    End If
                End If
                If failure Then
                    MessageBox.Show("The error occurs when creating a page nr." + i.ToString() + " or an action or a bookmark on this page. Status: " + gdpicturePDF.GetStat().ToString(), caption)
                End If
            Loop While Not failure AndAlso i < 10
        End If
        If Not failure Then
            failure = True
            rootBookmark = gdpicturePDF.NewBookmark(0, "Links Navigation")
            status = gdpicturePDF.GetStat()
            If status <> GdPictureStatus.OK Then
                MessageBox.Show("The NewBookmark() method (root bookmark for links) has failed with the status: " + status.ToString(), caption)
            Else
                Dim bookMarkID1 As Integer = gdpicturePDF.NewBookmark(rootBookmark, "Visit GdPicture website!")
                status = gdpicturePDF.GetStat()
                Dim bookMarkID2 As Integer = 0
                If status = GdPictureStatus.OK Then
                    bookMarkID2 = gdpicturePDF.NewBookmark(rootBookmark, "Read GdPicture.NET documentation online!")
                    status = gdpicturePDF.GetStat()
                End If
                If status = GdPictureStatus.OK Then
                    Dim actionID1 As Integer = gdpicturePDF.NewActionURI("http://www.gdpicture.com", False)
                    status = gdpicturePDF.GetStat()
                    Dim actionID2 As Integer = -1
                    If status = GdPictureStatus.OK Then
                        actionID2 = gdpicturePDF.NewActionURI("http://www.guides.gdpicture.com", False)
                        status = gdpicturePDF.GetStat()
                    End If
                    If status = GdPictureStatus.OK Then
                        failure = ((gdpicturePDF.SetBookmarkAction(bookMarkID1, actionID1) <> GdPictureStatus.OK) OrElse
                                   (gdpicturePDF.SetBookmarkAction(bookMarkID2, actionID2) <> GdPictureStatus.OK))
                        If failure Then
                            MessageBox.Show("This error occurs in creating the link navigation bookmark hierarchy: " + status.ToString(), caption)
                        End If
                    End If
                End If
            End If
        End If
        If Not failure Then
            status = gdpicturePDF.SaveToFile("bookmarks_NewBookmark.pdf")
            If status = GdPictureStatus.OK Then
                MessageBox.Show("The new file has been saved successfully.", caption)
            Else
                MessageBox.Show("The new file can't be saved. Status: " + status.ToString(), caption)
            End If
        End If
    End If
Else
    MessageBox.Show("The new file can't be created. Status: " + status.ToString(), caption)
End If
gdpicturePDF.Dispose()